哪位有经过验证的双字节的除法汇编程序？

老弹弓 · 发表于 2012-10-21 18:57

本帖最后由老弹弓于 2012-10-21 18:58 编辑

网上找了一个，在特定的数字时会出错。
;****************************************************
;* 四字节/两字节无符号数除法程序 *
;****************************************************
;  R7R6R5R4 / R3R2 = R7R6R5R4(商)  ...R1R0  (余数)
;
DIV4BY2:
            MOV    46H, #20H
            MOV    R0 , #00H
            MOV    R1 , #00H
DIVLOOP1:
            MOV    A  , R4
            RLC A
            MOV R4 , A
            MOV A  , R5
            RLC A
            MOV R5 , A
            MOV A  , R6
            RLC A
            MOV R6 , A
            MOV A  , R7
            RLC A
            MOV R7 , A
            MOV A  , R0
            RLC A
            MOV R0 , A
            MOV A  , R1
            RLC A
            MOV R1 , A
            CLR C
            MOV A  , R0
            SUBB  A  , R2
            MOV B  , A
            MOV A  , R1
            SUBB  A  , R3
            JC    DIVLOOP2
            MOV R0 , B
            MOV R1 , A
DIVLOOP2:
            CPL C
            DJNZ 46H, DIVLOOP1
            MOV A  , R4
            RLC A
            MOV R4 , A
            MOV A  , R5
            RLC A
            MOV R5 , A
            MOV A  , R6
            RLC A
            MOV R6 , A
            MOV A  , R7
            RLC A
            MOV R7 , A

            ret

younge · 发表于 2012-10-21 19:44

原理大概是分子分母同时除以2即右移一位，然后比较移位后分子分目的关系

老弹弓 · 发表于 2012-10-21 19:53

原理看的差不多了，不过程序差一点就不行了，不想再费事从头写了，干脆找个经过验证的读懂就可以了。

明白 · 发表于 2012-10-21 21:34

k可以用的：

;**************************************************** "
;* 四字节/两字节无符号数除法程序 *
;****************************************************
;  R4R5R6R7 / R2R3 = R4R5R6R7(商)  ...R2R3  (余数)

;=================================================
DIV4B:
               CLR A
               MOV R1,A
               MOV R0,A
               CJNE  R0,#00H,DIV4B_1
               CJNE  R1,#00H,DIV4B_2
               CJNE  R2,#00H,DIV4B_3
               MOV A,R4
               MOV B,R3
               DIV AB
               XCH A,R7
               XCH A,R6
               XCH A,R5
               MOV R4,A
               MOV A,B
               XCH A,R3
               MOV R1,A
               MOV R0,#18H
DIV4B_A:          MOV A,R7
               ADD A,R7
               MOV R7,A
               MOV A,R6
               RLC A
               MOV R6,A
               MOV A,R5
               RLC A
               MOV R5,A
               MOV A,R4
               RLC A
               MOV R4,A
               MOV A,R3
               RLC A
               MOV R3,A
               JBC CY,DIV4B_B
               SUBB  A,R1
               JC DIV4B_C
DIV4B_B:          MOV A,R3
               SUBB  A,R1
               MOV R3,A
               INC R7
DIV4B_C:          DJNZ  R0,DIV4B_A
               CLR A
               MOV R1,A
               MOV R2,A
               RET
;=================================================
DIV4B_1:          MOV B,#08H
               MOV DPL,#00H
DIV4B_11:       MOV A,R7
               ADD A,R7
            MOV R7,A
               MOV A,R6
               RLC A
               MOV R6,A
               XCH A,R5
               RLC A
               XCH A,R5
               XCH A,R4
               RLC A
               XCH A,R4
               XCH A,DPL
               RLC A
               XCH A,DPL
               SUBB  A,R3
               MOV A,R5
               SUBB  A,R2
               MOV A,R4
               SUBB  A,R1
               MOV A,DPL
               SUBB  A,R0
               JC DIV4B_12
               MOV DPL,A
               MOV A,R6
               SUBB  A,R3
               MOV R6,A
               MOV A,R5
               SUBB  A,R2
               MOV R5,A
               MOV A,R4
               SUBB  A,R1
               MOV R4,A
               INC R7
DIV4B_12:       DJNZ  B,DIV4B_11
               CLR A
               XCH A,R6
               MOV R3,A
               CLR A
               XCH A,R5
               MOV R2,A
               CLR A
               XCH A,R4
               MOV R1,A
               MOV R0,DPL
               RET
;================================================
DIV4B_2:          MOV B,#10H
DIV4B_21:       MOV A,R7
               ADD A,R7
               MOV R7,A
               MOV A,R6
               RLC A
               MOV R6,A
               MOV A,R5
               RLC A
               MOV R5,A
               XCH A,R4
               RLC A
               XCH A,R4
               XCH A,R0
               RLC A
               XCH A,R0
               JBC CY,DIV4B_22
               SUBB  A,R3
               MOV A,R4
               SUBB  A,R2
               MOV A,R0
               SUBB  A,R1
               JC DIV4B_23
DIV4B_22:       MOV A,R5
               SUBB  A,R3
               MOV R5,A
               MOV A,R4
               SUBB  A,R2
               MOV R4,A
               MOV A,R0
               SUBB  A,R1
               MOV R0,A
               INC R7
DIV4B_23:       DJNZ  B,DIV4B_21
               CLR A
               XCH A,R5
               MOV R3,A
               CLR A
               XCH A,R4
               MOV R2,A
               CLR A
               XCH A,R0
               MOV R1,A
               RET
;================================================
DIV4B_3:          MOV R0,#18H
DIV4B_31:       MOV A,R7
               ADD A,R7
               MOV R7,A
               MOV A,R6
               RLC A
               MOV R6,A
               MOV A,R5
               RLC A
               MOV R5,A
               MOV A,R4
               RLC A
               MOV R4,A
               XCH A,R1
               RLC A
               XCH A,R1
               JBC CY,DIV4B_32
               SUBB  A,R3
               MOV A,R1
               SUBB  A,R2
               JC DIV4B_33
DIV4B_32:       MOV A,R4
               SUBB  A,R3
               MOV R4,A
               MOV A,R1
               SUBB  A,R2
               MOV R1,A
               INC R7
DIV4B_33:       DJNZ  R0,DIV4B_31
               CLR A
               XCH A,R1
               MOV R2,A
               CLR A
               XCH A,R4
               MOV R3,A
               RET

明白 · 发表于 2012-10-21 21:35

DIV4B
是作为子程序，来调用的

明白 · 发表于 2012-10-21 21:37

注意我的赋值，高低字节跟你是刚好相反

灰灰的丝丁鱼 · 发表于 2012-10-21 22:06

还真没这样用过

老弹弓 · 发表于 2012-10-21 23:41

谢谢明白网友！慢慢拜读，虽然是抄别人的程序也要弄懂了才觉得踏实。

收音机 · 发表于 2012-10-29 04:22

自己在有显示界面的开发板上试验下就知道行不行了

老弹弓 · 发表于 2012-10-29 12:51

自己在有显示界面的开发板上试验下就知道行不行了
收音机发表于 2012-10-29 04:22 https://www.yleee.com.cn/images/common/back.gif

有的不行，不是所有的数不行，只是特定的数不行，比如我贴的那个，在除数高字节大于被除数第四字节时就出错，所以有板子也不是那么容易验证。

		自动登录	找回密码
密码			请使用微信账号登录和注册会员

[其他综合] 哪位有经过验证的 双字节的除法汇编程序？

[其他综合] 哪位有经过验证的双字节的除法汇编程序？