求一个PIC10F200的程序

小染染

那位老师能帮我 给PIC10F200个程序
或者 PIC10F220也行

实现单键开关的功能

就是 按一下 输出高电平 再按一下输出为0  如此往复~~

想用输出端来控制模拟开关

顺便求老师给个能烧写这种程序的地方~

淘宝上找的单片机编程和设计 问了几个 起价都是1000 2000 根本不理我。。。。

PS. 电路板空间非常非常小 10mm*10mm 还要 安装其他的原件 不想用其他的方式实现该功能~

zhuaii3721

用555难道不行吗？？？

小染染

zhuaii3721 发表于 2013-8-14 09:43
用555难道不行吗？？？

555 也是和PIC10F200 SOT-23一样尺寸的么？ 还是更小？

zhuaii3721

小染染 发表于 2013-8-14 09:56
555 也是和PIC10F200 SOT-23一样尺寸的么？ 还是更小？

那就不是了～～～～～

gw168sh

SOT23-6的啊，
俺的K150貌似不支持
其实STM8S103F2也蛮小的

ldch

    processor 10F200
    #include <P10F200.INC>

__CONFIG _MCLRE_OFF&_CP_ON&_WDT_OFF&_IntRC_OSC
;----------------------------------------------
DELY1 EQU 10H
DELY2 EQU 11H
KEY EQU 12H
;----------------------------------------------------------
        ORG 00H                ;复位向量地址
STAR    MOVLW 09H
        TRIS GPIO
        MOVLW 87H
        OPTION                ;允许弱上拉
        CLRF GPIO
        CLRF KEY
;-------------------------------------------------
LOOP
       BTFSC GPIO,00H
       GOTO LOOP
       CALL DELAY10MS
       BTFSC GPIO,00H
       GOTO LOOP
       BTFSS GPIO,00H
       GOTO $-1
     
        BTFSC KEY,02H
        GOTO SETKEY
        BSF KEY,02H
        MOVF KEY,W
        MOVWF GPIO
        GOTO LOOP

SETKEY
        BCF KEY,02H
        MOVF KEY,W
        MOVWF GPIO
        GOTO LOOP
;**************************************************       
DELAY10MS
        MOVLW         10H                                        ;外循环常数
        MOVWF         DELY1                                        ;外循环寄存器
LOOP0        MOVLW         0E6H                                        ;中循环常数
        MOVWF         DELY2                                        ;中循环寄存器
LOOP1        DECFSZ         DELY2,F                                        ;中循环寄存器递减
        GOTO         LOOP1                                        ;继续中循环
        DECFSZ         DELY1,F                                        ;外循环寄存器递减
        GOTO         LOOP0                                        ;继续外循环
        RETLW 00H
;----------------------------------------------------------
END

小染染

ldch 发表于 2013-8-14 11:37
processor 10F200
    #include

谢谢您的帮助
但是还有些问题想请教您

请问 按照您这个程序  以下的 哪个脚是输入 哪个脚是输出啊 输出的是高电平么？


还有 您给的这个程序 带按键防抖功能么？

要是想实现下图的这种功能应该怎么改写程序呀？

ldch

GP0对地接按键，GP2输出。上面这个图，按键另一端接地就OK了

小染染

ldch 发表于 2013-8-14 11:59
GP0对地接按键，GP2输出。上面这个图，按键另一端接地就OK了

请问 您的意思是 您给的这个图和我发的图片是完全对应的么？

还有 您的程序有没有做按键防抖的处理啊？

我对单片机的程序一窍不通  再次感谢您的帮助与解答

ldch

按键防抖已经有了
基本上是对应的，只是按键另一端要接地，你那个图，按键另一端是接VCC的，刚好相反。